tenant.openagents/omega

1; Variables
2(identifier) @variable
3
4(call_expression
5  function: (member_expression
6    object: (identifier) @type
7    (#any-of? @type
8      "Promise" "Array" "Object" "Map" "Set" "WeakMap" "WeakSet" "Date" "Error" "TypeError"
9      "RangeError" "SyntaxError" "ReferenceError" "EvalError" "URIError" "RegExp" "Function"
10      "Number" "String" "Boolean" "Symbol" "BigInt" "Proxy" "ArrayBuffer" "DataView")))
11
12; Properties
13(property_identifier) @property
14
15(shorthand_property_identifier) @property
16
17(shorthand_property_identifier_pattern) @property
18
19(private_property_identifier) @property
20
21; Function and method calls
22(call_expression
23  function: (identifier) @function)
24
25(call_expression
26  function: (member_expression
27    property: [
28      (property_identifier)
29      (private_property_identifier)
30    ] @function.method))
31
32(new_expression
33  constructor: (identifier) @type)
34
35(nested_type_identifier
36  module: (identifier) @type)
37
38; Function and method definitions
39(function_expression
40  name: (identifier) @function)
41
42(function_declaration
43  name: (identifier) @function)
44
45(method_definition
46  name: [
47    (property_identifier)
48    (private_property_identifier)
49  ] @function.method)
50
51(method_definition
52  name: (property_identifier) @constructor
53  (#eq? @constructor "constructor"))
54
55(pair
56  key: [
57    (property_identifier)
58    (private_property_identifier)
59  ] @function.method
60  value: [
61    (function_expression)
62    (arrow_function)
63  ])
64
65(assignment_expression
66  left: (member_expression
67    property: [
68      (property_identifier)
69      (private_property_identifier)
70    ] @function.method)
71  right: [
72    (function_expression)
73    (arrow_function)
74  ])
75
76(variable_declarator
77  name: (identifier) @function
78  value: [
79    (function_expression)
80    (arrow_function)
81  ])
82
83(assignment_expression
84  left: (identifier) @function
85  right: [
86    (function_expression)
87    (arrow_function)
88  ])
89
90; Parameters
91(required_parameter
92  (identifier) @variable.parameter)
93
94(required_parameter
95  (_
96    ([
97      (identifier)
98      (shorthand_property_identifier_pattern)
99    ]) @variable.parameter))
100
101(required_parameter
102  (_
103    (object_assignment_pattern
104      left: (shorthand_property_identifier_pattern) @variable.parameter)))
105
106(required_parameter
107  (_
108    (assignment_pattern
109      left: (identifier) @variable.parameter)))
110
111(optional_parameter
112  (_
113    (object_assignment_pattern
114      left: (shorthand_property_identifier_pattern) @variable.parameter)))
115
116(optional_parameter
117  (_
118    (assignment_pattern
119      left: (identifier) @variable.parameter)))
120
121(optional_parameter
122  (identifier) @variable.parameter)
123
124(optional_parameter
125  (_
126    ([
127      (identifier)
128      (shorthand_property_identifier_pattern)
129    ]) @variable.parameter))
130
131(catch_clause
132  parameter: (identifier) @variable.parameter)
133
134(index_signature
135  name: (identifier) @variable.parameter)
136
137(arrow_function
138  parameter: (identifier) @variable.parameter)
139
140(type_predicate
141  name: (identifier) @variable.parameter)
142
143; Special identifiers
144(type_annotation) @type
145
146(type_identifier) @type
147
148(predefined_type) @type.builtin
149
150(type_alias_declaration
151  (type_identifier) @type)
152
153(type_alias_declaration
154  value: (_
155    (type_identifier) @type))
156
157(interface_declaration
158  (type_identifier) @type)
159
160(class_declaration
161  (type_identifier) @type.class)
162
163(extends_clause
164  value: (identifier) @type.class)
165
166(extends_type_clause
167  type: (type_identifier) @type)
168
169(implements_clause
170  (type_identifier) @type)
171
172([
173  (identifier)
174  (shorthand_property_identifier)
175  (shorthand_property_identifier_pattern)
176] @constant
177  (#match? @constant "^_*[A-Z_][A-Z\\d_]*$"))
178
179; Literals
180(this) @variable.special
181
182(super) @variable.special
183
184[
185  (null)
186  (undefined)
187] @constant.builtin
188
189[
190  (true)
191  (false)
192] @boolean
193
194(comment) @comment
195
196[
197  (string)
198  (template_string)
199  (template_literal_type)
200] @string
201
202(escape_sequence) @string.escape
203
204(regex) @string.regex
205
206(regex_flags) @keyword.operator.regex
207
208(number) @number
209
210; Tokens
211[
212  ";"
213  "?."
214  "."
215  ","
216  ":"
217  "?"
218] @punctuation.delimiter
219
220[
221  "-"
222  "--"
223  "-="
224  "+"
225  "++"
226  "+="
227  "*"
228  "*="
229  "**"
230  "**="
231  "/"
232  "/="
233  "%"
234  "%="
235  "<"
236  "<="
237  "<<"
238  "<<="
239  "="
240  "=="
241  "==="
242  "!"
243  "!="
244  "!=="
245  "=>"
246  ">"
247  ">="
248  ">>"
249  ">>="
250  ">>>"
251  ">>>="
252  "~"
253  "^"
254  "&"
255  "|"
256  "^="
257  "&="
258  "|="
259  "&&"
260  "||"
261  "??"
262  "&&="
263  "||="
264  "??="
265  "..."
266] @operator
267
268(regex
269  "/" @string.regex)
270
271[
272  "("
273  ")"
274  "["
275  "]"
276  "{"
277  "}"
278] @punctuation.bracket
279
280(ternary_expression
281  [
282    "?"
283    ":"
284  ] @operator)
285
286; Keywords
287[
288  "abstract"
289  "as"
290  "async"
291  "debugger"
292  "declare"
293  "default"
294  "delete"
295  "extends"
296  "get"
297  "implements"
298  "in"
299  "infer"
300  "instanceof"
301  "is"
302  "keyof"
303  "module"
304  "namespace"
305  "new"
306  "of"
307  "override"
308  "private"
309  "protected"
310  "public"
311  "readonly"
312  "satisfies"
313  "set"
314  "static"
315  "target"
316  "typeof"
317  "using"
318  "void"
319  "with"
320] @keyword
321
322[
323  "const"
324  "let"
325  "var"
326  "function"
327  "class"
328  "enum"
329  "interface"
330  "type"
331] @keyword.declaration
332
333[
334  "export"
335  "from"
336  "import"
337] @keyword.import
338
339[
340  "await"
341  "break"
342  "case"
343  "catch"
344  "continue"
345  "do"
346  "else"
347  "finally"
348  "for"
349  "if"
350  "return"
351  "switch"
352  "throw"
353  "try"
354  "while"
355  "yield"
356] @keyword.control
357
358(switch_default
359  "default" @keyword.control)
360
361(template_substitution
362  "${" @punctuation.special
363  "}" @punctuation.special) @embedded
364
365(template_type
366  "${" @punctuation.special
367  "}" @punctuation.special) @embedded
368
369(type_arguments
370  "<" @punctuation.bracket
371  ">" @punctuation.bracket)
372
373(type_parameters
374  "<" @punctuation.bracket
375  ">" @punctuation.bracket)
376
377(decorator
378  "@" @punctuation.special)
379
380(union_type
381  "|" @punctuation.special)
382
383(intersection_type
384  "&" @punctuation.special)
385
386(type_annotation
387  ":" @punctuation.special)
388
389(index_signature
390  ":" @punctuation.special)
391
392(type_predicate_annotation
393  ":" @punctuation.special)
394
395(public_field_definition
396  "?" @punctuation.special)
397
398(property_signature
399  "?" @punctuation.special)
400
401(method_signature
402  "?" @punctuation.special)
403
404(optional_parameter
405  ([
406    "?"
407    ":"
408  ]) @punctuation.special)
409
410(jsx_opening_element
411  [
412    (identifier) @type @tag.component.jsx
413    (member_expression
414      object: (identifier) @type @tag.component.jsx
415      property: (property_identifier) @type @tag.component.jsx)
416    (member_expression
417      object: (member_expression
418        object: (identifier) @type @tag.component.jsx
419        property: (property_identifier) @type @tag.component.jsx)
420      property: (property_identifier) @type @tag.component.jsx)
421    (member_expression
422      object: (member_expression
423        object: (member_expression
424          object: (identifier) @type @tag.component.jsx
425          property: (property_identifier) @type @tag.component.jsx)
426        property: (property_identifier) @type @tag.component.jsx)
427      property: (property_identifier) @type @tag.component.jsx)
428  ])
429
430(jsx_closing_element
431  [
432    (identifier) @type @tag.component.jsx
433    (member_expression
434      object: (identifier) @type @tag.component.jsx
435      property: (property_identifier) @type @tag.component.jsx)
436    (member_expression
437      object: (member_expression
438        object: (identifier) @type @tag.component.jsx
439        property: (property_identifier) @type @tag.component.jsx)
440      property: (property_identifier) @type @tag.component.jsx)
441    (member_expression
442      object: (member_expression
443        object: (member_expression
444          object: (identifier) @type @tag.component.jsx
445          property: (property_identifier) @type @tag.component.jsx)
446        property: (property_identifier) @type @tag.component.jsx)
447      property: (property_identifier) @type @tag.component.jsx)
448  ])
449
450(jsx_self_closing_element
451  [
452    (identifier) @type @tag.component.jsx
453    (member_expression
454      object: (identifier) @type @tag.component.jsx
455      property: (property_identifier) @type @tag.component.jsx)
456    (member_expression
457      object: (member_expression
458        object: (identifier) @type @tag.component.jsx
459        property: (property_identifier) @type @tag.component.jsx)
460      property: (property_identifier) @type @tag.component.jsx)
461    (member_expression
462      object: (member_expression
463        object: (member_expression
464          object: (identifier) @type @tag.component.jsx
465          property: (property_identifier) @type @tag.component.jsx)
466        property: (property_identifier) @type @tag.component.jsx)
467      property: (property_identifier) @type @tag.component.jsx)
468  ])
469
470(jsx_opening_element
471  (identifier) @tag.jsx
472  (#match? @tag.jsx "^[a-z][^.]*$"))
473
474(jsx_closing_element
475  (identifier) @tag.jsx
476  (#match? @tag.jsx "^[a-z][^.]*$"))
477
478(jsx_self_closing_element
479  (identifier) @tag.jsx
480  (#match? @tag.jsx "^[a-z][^.]*$"))
481
482(jsx_attribute
483  (property_identifier) @attribute.jsx)
484
485(jsx_opening_element
486  ([
487    "<"
488    ">"
489  ]) @punctuation.bracket.jsx)
490
491(jsx_closing_element
492  ([
493    "</"
494    ">"
495  ]) @punctuation.bracket.jsx)
496
497(jsx_self_closing_element
498  ([
499    "<"
500    "/>"
501  ]) @punctuation.bracket.jsx)
502
503(jsx_attribute
504  "=" @punctuation.delimiter.jsx)
505
506(jsx_text) @text.jsx
507
508(html_character_reference) @string.special
509