tenant.openagents/omega

1; Variables
2(identifier) @variable
3
4(call_expression
5  function: (member_expression
6    object: (identifier) @type
7    (#any-of? @type
8      "Promise" "Array" "Object" "Map" "Set" "WeakMap" "WeakSet" "Date" "Error" "TypeError"
9      "RangeError" "SyntaxError" "ReferenceError" "EvalError" "URIError" "RegExp" "Function"
10      "Number" "String" "Boolean" "Symbol" "BigInt" "Proxy" "ArrayBuffer" "DataView")))
11
12; Properties
13(property_identifier) @property
14
15(shorthand_property_identifier) @property
16
17(shorthand_property_identifier_pattern) @property
18
19(private_property_identifier) @property
20
21; Function and method calls
22(call_expression
23  function: (identifier) @function)
24
25(call_expression
26  function: (member_expression
27    property: [
28      (property_identifier)
29      (private_property_identifier)
30    ] @function.method))
31
32(new_expression
33  constructor: (identifier) @type)
34
35(nested_type_identifier
36  module: (identifier) @type)
37
38; Function and method definitions
39(function_expression
40  name: (identifier) @function)
41
42(function_declaration
43  name: (identifier) @function)
44
45(method_definition
46  name: [
47    (property_identifier)
48    (private_property_identifier)
49  ] @function.method)
50
51(method_definition
52  name: (property_identifier) @constructor
53  (#eq? @constructor "constructor"))
54
55(pair
56  key: [
57    (property_identifier)
58    (private_property_identifier)
59  ] @function.method
60  value: [
61    (function_expression)
62    (arrow_function)
63  ])
64
65(assignment_expression
66  left: (member_expression
67    property: [
68      (property_identifier)
69      (private_property_identifier)
70    ] @function.method)
71  right: [
72    (function_expression)
73    (arrow_function)
74  ])
75
76(variable_declarator
77  name: (identifier) @function
78  value: [
79    (function_expression)
80    (arrow_function)
81  ])
82
83(assignment_expression
84  left: (identifier) @function
85  right: [
86    (function_expression)
87    (arrow_function)
88  ])
89
90; Parameters
91(required_parameter
92  (identifier) @variable.parameter)
93
94(required_parameter
95  (_
96    ([
97      (identifier)
98      (shorthand_property_identifier_pattern)
99    ]) @variable.parameter))
100
101(required_parameter
102  (_
103    (object_assignment_pattern
104      left: (shorthand_property_identifier_pattern) @variable.parameter)))
105
106(required_parameter
107  (_
108    (assignment_pattern
109      left: (identifier) @variable.parameter)))
110
111(optional_parameter
112  (_
113    (object_assignment_pattern
114      left: (shorthand_property_identifier_pattern) @variable.parameter)))
115
116(optional_parameter
117  (_
118    (assignment_pattern
119      left: (identifier) @variable.parameter)))
120
121(optional_parameter
122  (identifier) @variable.parameter)
123
124(optional_parameter
125  (_
126    ([
127      (identifier)
128      (shorthand_property_identifier_pattern)
129    ]) @variable.parameter))
130
131(catch_clause
132  parameter: (identifier) @variable.parameter)
133
134(index_signature
135  name: (identifier) @variable.parameter)
136
137(arrow_function
138  parameter: (identifier) @variable.parameter)
139
140; Special identifiers
141;
142(type_identifier) @type
143
144(predefined_type) @type.builtin
145
146(class_declaration
147  (type_identifier) @type.class)
148
149(extends_clause
150  value: (identifier) @type.class)
151
152([
153  (identifier)
154  (shorthand_property_identifier)
155  (shorthand_property_identifier_pattern)
156] @constant
157  (#match? @constant "^_*[A-Z_][A-Z\\d_]*$"))
158
159; Literals
160(this) @variable.special
161
162(super) @variable.special
163
164[
165  (null)
166  (undefined)
167] @constant.builtin
168
169[
170  (true)
171  (false)
172] @boolean
173
174(comment) @comment
175
176(hash_bang_line) @comment
177
178[
179  (string)
180  (template_string)
181] @string
182
183(escape_sequence) @string.escape
184
185(regex) @string.regex
186
187(regex_flags) @keyword.operator.regex
188
189(number) @number
190
191; Tokens
192[
193  ";"
194  "?."
195  "."
196  ","
197  ":"
198] @punctuation.delimiter
199
200[
201  "-"
202  "--"
203  "-="
204  "+"
205  "++"
206  "+="
207  "*"
208  "*="
209  "**"
210  "**="
211  "/"
212  "/="
213  "%"
214  "%="
215  "<"
216  "<="
217  "<<"
218  "<<="
219  "="
220  "=="
221  "==="
222  "!"
223  "!="
224  "!=="
225  "=>"
226  ">"
227  ">="
228  ">>"
229  ">>="
230  ">>>"
231  ">>>="
232  "~"
233  "^"
234  "&"
235  "|"
236  "^="
237  "&="
238  "|="
239  "&&"
240  "||"
241  "??"
242  "&&="
243  "||="
244  "??="
245  "..."
246] @operator
247
248(regex
249  "/" @string.regex)
250
251[
252  "("
253  ")"
254  "["
255  "]"
256  "{"
257  "}"
258] @punctuation.bracket
259
260(ternary_expression
261  [
262    "?"
263    ":"
264  ] @operator)
265
266[
267  "abstract"
268  "as"
269  "async"
270  "debugger"
271  "declare"
272  "default"
273  "delete"
274  "extends"
275  "get"
276  "implements"
277  "in"
278  "instanceof"
279  "keyof"
280  "module"
281  "namespace"
282  "new"
283  "of"
284  "override"
285  "private"
286  "protected"
287  "public"
288  "readonly"
289  "set"
290  "static"
291  "target"
292  "typeof"
293  "using"
294  "void"
295  "with"
296] @keyword
297
298[
299  "const"
300  "let"
301  "var"
302  "function"
303  "class"
304  "enum"
305  "interface"
306  "type"
307] @keyword.declaration
308
309[
310  "export"
311  "from"
312  "import"
313] @keyword.import
314
315[
316  "await"
317  "break"
318  "case"
319  "catch"
320  "continue"
321  "do"
322  "else"
323  "finally"
324  "for"
325  "if"
326  "return"
327  "switch"
328  "throw"
329  "try"
330  "while"
331  "yield"
332] @keyword.control
333
334(switch_default
335  "default" @keyword.control)
336
337(template_substitution
338  "${" @punctuation.special
339  "}" @punctuation.special) @embedded
340
341(type_arguments
342  "<" @punctuation.bracket
343  ">" @punctuation.bracket)
344
345(decorator
346  "@" @punctuation.special)
347
348; JSX elements
349(jsx_opening_element
350  [
351    (identifier) @type @tag.component.jsx
352    (member_expression
353      object: (identifier) @type @tag.component.jsx
354      property: (property_identifier) @type @tag.component.jsx)
355    (member_expression
356      object: (member_expression
357        object: (identifier) @type @tag.component.jsx
358        property: (property_identifier) @type @tag.component.jsx)
359      property: (property_identifier) @type @tag.component.jsx)
360    (member_expression
361      object: (member_expression
362        object: (member_expression
363          object: (identifier) @type @tag.component.jsx
364          property: (property_identifier) @type @tag.component.jsx)
365        property: (property_identifier) @type @tag.component.jsx)
366      property: (property_identifier) @type @tag.component.jsx)
367  ])
368
369(jsx_closing_element
370  [
371    (identifier) @type @tag.component.jsx
372    (member_expression
373      object: (identifier) @type @tag.component.jsx
374      property: (property_identifier) @type @tag.component.jsx)
375    (member_expression
376      object: (member_expression
377        object: (identifier) @type @tag.component.jsx
378        property: (property_identifier) @type @tag.component.jsx)
379      property: (property_identifier) @type @tag.component.jsx)
380    (member_expression
381      object: (member_expression
382        object: (member_expression
383          object: (identifier) @type @tag.component.jsx
384          property: (property_identifier) @type @tag.component.jsx)
385        property: (property_identifier) @type @tag.component.jsx)
386      property: (property_identifier) @type @tag.component.jsx)
387  ])
388
389(jsx_self_closing_element
390  [
391    (identifier) @type @tag.component.jsx
392    (member_expression
393      object: (identifier) @type @tag.component.jsx
394      property: (property_identifier) @type @tag.component.jsx)
395    (member_expression
396      object: (member_expression
397        object: (identifier) @type @tag.component.jsx
398        property: (property_identifier) @type @tag.component.jsx)
399      property: (property_identifier) @type @tag.component.jsx)
400    (member_expression
401      object: (member_expression
402        object: (member_expression
403          object: (identifier) @type @tag.component.jsx
404          property: (property_identifier) @type @tag.component.jsx)
405        property: (property_identifier) @type @tag.component.jsx)
406      property: (property_identifier) @type @tag.component.jsx)
407  ])
408
409(jsx_opening_element
410  (identifier) @tag.jsx
411  (#match? @tag.jsx "^[a-z][^.]*$"))
412
413(jsx_closing_element
414  (identifier) @tag.jsx
415  (#match? @tag.jsx "^[a-z][^.]*$"))
416
417(jsx_self_closing_element
418  (identifier) @tag.jsx
419  (#match? @tag.jsx "^[a-z][^.]*$"))
420
421(jsx_attribute
422  (property_identifier) @attribute.jsx)
423
424(jsx_opening_element
425  ([
426    "<"
427    ">"
428  ]) @punctuation.bracket.jsx)
429
430(jsx_closing_element
431  ([
432    "</"
433    ">"
434  ]) @punctuation.bracket.jsx)
435
436(jsx_self_closing_element
437  ([
438    "<"
439    "/>"
440  ]) @punctuation.bracket.jsx)
441
442(jsx_attribute
443  "=" @punctuation.delimiter.jsx)
444
445(jsx_text) @text.jsx
446
447(html_character_reference) @string.special
448